通过AIR Native Extension在AIR应用中加入iAd广告(二) —— Flash Pro篇

通过AIR Native Extension在AIR应用中加入iAd广告(一) —— Flash Builder篇 已经介绍了如果在Flash Builder上使用iAd扩展.今天讲讲如何使用Flash Pro发布程序.

1. 新建AIR for iOS项目;

2. 将上文提到的iAd_signed.ane重命名为iAd_signed.swc;

3. 打开高级ActionScript 3.0设置, 切换到”库路径”面板.把第2步修改的SWC文件添加到类库中;

4. 展开iAd_signed.swc前面的箭头, 双击”链接类型”为”外部”;

5. 编写舞台类

 

package 
{
 
	import flash.display.MovieClip;
	import flash.events.Event;
	import com.adobe.nativeExtensions.AdBanner;
	import com.adobe.nativeExtensions.AdBannerEvent;
	import com.adobe.nativeExtensions.AdBannerPosition;
 
	public class Main extends MovieClip
	{
 
		public function Main()
		{
			trace("Init...");
			this.addEventListener(Event.ADDED_TO_STAGE, onAddedToStage);
		}
 
		private function onAddedToStage(event:Event):void
		{
			this.removeEventListener(Event.ADDED_TO_STAGE, onAddedToStage);
			initAD();
		}
 
		private function initAD():void
		{
			AdBanner.adView.startShowingAds(AdBannerPosition.TOP, true);
			AdBanner.adView.addEventListener(AdBannerEvent.AD_LOADED, adLoaded);
			AdBanner.adView.addEventListener(AdBannerEvent.AD_LOADING_FAILED, adFailed);
			AdBanner.adView.addEventListener(AdBannerEvent.USER_INTERACTION_STARTING, adStart);
			AdBanner.adView.addEventListener(AdBannerEvent.USER_INTERACTION_FINISHED, adFinished);
		}
 
		private function adLoaded(event:AdBannerEvent):void
		{
			trace("Ad Loaded");
			AdBanner.adView.visible = true;
			trace("leaving: " + event.leaving);
		}
 
		private function adFailed(event:AdBannerEvent):void
		{
			trace("Loaded Failded: " + event.errorCode);
			AdBanner.adView.visible = false;
		}
 
		private function adStart(event:AdBannerEvent):void
		{
			trace("Starting");
			trace(stage.orientation);
		}
 
		private function adFinished(event:AdBannerEvent):void
		{
			trace("Finished");
			trace(stage.orientation);
		}
 
	}
}

6. CTRL+ENTER编译, 会有个VerifyError: Error #1014: Class com.adobe.nativeExtensions::AdBannerEvent could not be found错误. 不用理会.继续下步.

7. 新建ane文件夹, 将iAd_signed.ane复制进去

8. 进行AIR for iOS设置

9. 将Flash CS生成的t-app.xml复制一份并命名为new-t.xml, 打开new-t.xml, 加入

 <extensions>
<extensionID>com.adobe.iad</extensionID>
</extensions>

10. 用ADT打包工具打包.

adt.bat -package -target ipa-app-store -provisioning-profile t.mobileprovision -storetype pkcs12 -keystore t.p12 -storepass 1234 t.ipa new-t.xml t.swf -extdir ane

打包为发行版本 -package -target ipa-app-store

指定provisioning文件 -provisioning-profile t.mobileprovision

指定证书文件 -storetype pkcs12 -keystore t.p12

指定证书密码 -storepass 1234

导出文件名 t.ipa

配置文件 new-t.xml

第6步编译的SWF文件 t.swf

指定扩展的路径(第7步新建的文件夹) -extdir ane

11. 连接设备, 安装打包好的ipa文件测试

 

程序源代码,证书(密码1234): 点击此处下载

22 comments to 通过AIR Native Extension在AIR应用中加入iAd广告(二) —— Flash Pro篇

Leave a Reply

 

 

 

You can use these HTML tags

<a href="" title=""> <abbr title=""> <acronym title=""> <b> <blockquote cite=""> <cite> <code> <del datetime=""> <em> <i> <q cite=""> <s> <strike> <strong> <pre lang="" line="" escaped="">